马上重启,关机,注销,批处理应该怎么写?
发布网友
发布时间：2022-04-22 06:33
共4个回答
热心网友
时间：2023-06-25 14:15
shutdown.exe -a 取消关机
shutdown.exe -f 强行关闭应用程序。
shutdown.exe -m \计算机名 控制远程计算机。
shutdown.exe -i 显示图形用户界面，但必须是Shutdown的第一个参数。
shutdown.exe -l 注销当前用户。
shutdown.exe -r 关机并重启。
shutdown.exe -t时间 设置关机倒计时。
shutdown.exe -c"消息内容" 输入关机对话框中的消息内容(不能超127个字符)。
比如你的电脑要在23:00关机，可以选择“开始→运行”，输入“at 23:00 Shutdown -s”，这样，到了23点，电脑就会出现“系统关机”对话框
shutdown -r -t 60 -c 系统关机 意思为 60秒后重启,对话框上显示 "系统关机"
因系统而异
热心网友
时间：2023-06-25 14:16
注销不会，但是重启和关机会的。
具体用法查看shutdown /?
重启：
@echo off
shutdown -r
EXIT
关机：
@echo off
shutdown -s
以上命令在其后加入“-t xx”可以设置倒数时间。
热心网友
时间：2023-06-25 14:16
在开始-运行 里面直接 输入 shutdown -r -t 1 -c 就是1秒钟后马上关机
没必要搞那么麻烦啦，有现成的功能不用，何必去搞个批处理
热心网友
时间：2023-06-25 14:17
@echo off & cls & color 2f & mode con cols=62 lines=20 & title [定时关机工具] %date:~0,4%年%date:~5,2%月%date:~8,2%日,%time:~0,2%点%time:~3,2%分%time:~6,5%秒
set n=10080
:home
cls
echo.
echo 温馨提示:爱机也需休息!
echo.
echo 注意:如定时错误,可重启本程序输入[O]取消定时,然后
echo 重新定时即可.本程序适用于WIN XP操作系统.
echo.
echo 更多小工具请加P处理爱好者群:2392905.
echo zjl程序制作,于2007年4月2日3点25分.
echo.
echo [S].定时关机 [R].定时重启 [O].取消定时
echo.
echo [G].立即关机 [C].立即重启 [E].放弃退出
echo.
set /P a= 请选择操作代号:
SET w1=R S O E G C
FOR %%B IN (%w1%) DO IF /I "%a%"=="%%B" set flag=1
ECHO.
if defined flag (
goto :%a%
) else (
SET /P N= 请选择选项里应有的操作.[Y-继续]:
)
IF /I "%N%"=="Y" (GOTO :home) ELSE (exit)
:S
Set /p time= 请输入关机倒计时间(分钟),Q-返回:
ECHO.
if /i "%time%"=="q" goto :home
if %time% lss 1 (
echo 因关机时不保存数据,避免损失,倒计时间不得少于1分钟.
echo.
echo 如想快速关机,请返回主菜单,[G]键立即关机.
echo.
goto :s
)
if %time% lss %n% (goto :gj) else (
echo 注意:时间必须为纯数字,并且倒计时间不得大于10080分钟.
echo.
goto :s)
:gj
set /a time1=%time%*60
shutdown -s -f -c "你输入的是%time%分钟后关机" -t %time1%
goto :q
:R
Set /p time= 请输入重启倒计时间(分钟),Q-返回:
ECHO.
if /i "%time%"=="q" goto :home
if %time% lss 1 (
echo 因重启时不保存数据,避免损失,倒计时间不得少于1分钟.
echo.
echo 如想快速重启,请返回主菜单,[C]键立即重启.
echo.
goto :r
)
if %time% lss %n% (goto :cq) else (
echo 注意:时间必须为纯数字,并且倒计时间不得大于10080分钟.
echo.
goto :r)
:cq
set /a time1=%time%*60
shutdown -R -f -c "你输入的是%time%分钟后重启" -t %time1%
goto :q
:o
shutdown -a | find "没有" >nul
if "%ERRORLEVEL%"=="0" echo 没有关机任务!
echo.
goto :q
:g
shutdown -F -S -T 0
goto :q
:c
shutdown -F -R -T 0
goto :q
:q
echo 操作成功 ! 任意键返回...
pause >nul
goto :home
:E
exit
